Introduction
Lorsque votre application AIR sert à saisir des données et les manipuler, il est utile de pouvoir sauvegarder ces données afin de pouvoir les charger ultérieurement.
Il est aussi utile d’associer une extension à ce document afin de pouvoir lancer l’application en chargeant automatiquement vos données. Le document sauvegardé peut aussi contenir des informations sur la position de la fenêtre de l’application et les préférences utilisateurs. Ainsi, au démarrage de l’application, on peut restituer les données et les préférences utilisateur.
Problématique:
Comment sauvegarder votre VO dans un fichier et comment le charger à partir de ce fichier ?
Comment lancer votre application et charger vos données à exécution de ce fichier ?
Voir la procédure !
Tutoriel
1/5 – Créer une Classe Remote
Cette classe contient vos VO.
[RemoteClass]
public class SaveData
{
public var user:UserVO;
public var prefs:PreferencesVO;
}
Ensuite, il suffit de créer une instance de SaveData avec vos VO comme propriétés.
saver:SaveData = new SaveData(); saver.user = myUser; saver.prefs = myPrefs;
2/5 – Sauvegarder le Fichier
Nous allons utiliser la classe File pour afficher une fenêtre de sauvegarde du fichier :
private function displaySaveWindow(event:MouseEvent):void
{
var file:File = File.documentsDirectory; //Se placer dans le répertoire "Documents"
try
{
file.browseForSave("Save Project As");
file.addEventListener(Event.SELECT, saveProject); //Appeler la méthode saveProject lorsque l'utilisateur sélectionne un fichier de sauvegarde
}
catch (error:Error)
{
trace("Failed:", error.message);
}
}
Une fois le fichier de sauvegarde sélectionné, on va rajouter l’extension souhaitée au cas où l’utilisateur ne la rajoute pas au nom du fichier.
Dans L’exemple suivant, l’extension choisie est « .kap ». Ensuite nous créons un objet SaveData en y rajoutant les données à sauvegarder myUser et myPrefs en propriétés. La dernière étape est d’écrire les données (saver) dans le fichier selectionné (newFile) en utilisant la méthode writeObjectToFile (détails dans le paragraphe suivant).
private function saveProject(event:Event):void
{
var newFile:File = event.target as File;
if(newFile.url.substring(newFile.url.lastIndexOf("."),newFile.url.length) != ".kap")
newFile.url += ".kap"; //Rajouter l'extension si elle n'existe pas dans le nom du fichier
var saver:SaveData = new SaveData();
saver.user = myUser;
saver.prefs = myPrefs;
FileSerializer.writeObjectToFile(saver, newFile);
}
3/5 – Ecrire les Données dans le Fichier
Afin d’écrire l’objet saver qui contient toute les informations à sauvegarder dans le fichier, il faut le sérialiser. Ceci peut être réalisé en utilisant la méthode writeObject de la classe FileStream du framework AIR.
La méthode suivante prend en arguments :
- L’objet à sérialiser et sauvegarder
- Le fichier dans lequel on va écrire cet objet
public class FileSerializer
{
public static function writeObjectToFile(object:Object, file:File):void
{
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeObject(object);
fileStream.close();
}
}
4/5 – Affecter l’Extension de Fichier Choisie à Votre Application
Pour associer une extension à votre application AIR, éditez le fichier XML de configuration de l’application. Dans ce fichier, vous pouvez définir l’icône des fichiers associés à votre application. Trouver le bloc suivant et éditez le de la façon suivante : (n’oubliez pas de dé-commenter le bloc !)
<fileTypes> <fileType> <name>MonApplication.KAPFile</name> <extension>kap</extension> <description>KAP File</description> <contentType>application/monapplication.kap-file</contentType> <icon> <image128x128>logo_monapplication_kap.png</image128x128> </icon> </fileType> </fileTypes>
Une bonne idée est d’associer une icône à votre application en dé-commentant le bloc suivant et en indiquant le chemin vers l’icône.
<icon> <image128x128>logo_monapplication_kap.png</image128x128> </icon>
Pour voir le résultat, il faut faire un Release Build de l’application et installer le .air. L’exécuteur adl (celui utilisé par Flex Builder par exemple) ne permet pas d’affecter l’extension à vos fichiers.
5/5 – Récupérer les Données Lors de l’Exécution du Fichier Sauvegardé
Après avoir installé l’application AIR sur votre système, vous remarquez que le fichier « .kap » devient exécutable et lance votre application AIR. Mais comment récupérer les données du fichier au lancement ?
L’événement invoke est dispatché lorsque l’application est invoquée. C’est le cas du lancement de l’application à l’exécution du fichier qui porte une extension qui y est associée.
Il suffit alors d’écouter l’évenement invoke qui contient une propriété arguments qui contient à son tour les URL des fichiers sélectionnés pour l’exécution de l’application.
D’abord nous récupérons l’URL du fichier à partir de l’événement, ensuite on instancie un objet File à partir de cet URL et on le passe à la fonction readObjectFromFile pour dé-sérialiser l’objet. Une fois l’objet dé-sérialisé, nous pouvons récupérer nos VO sauvegardés.
Voici le code:
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml"
layout="absolute"
width="300"
height="300"
invoke="onInvoke" >
private function onInvoke(e:InvokeEvent):void
{
if (e.arguments[0])
{
var loadedFile:File = new File(e.arguments[0].toString());
loadedFileData = FileSerializer.readObjectFromFile(loadedFile) as SaveData; //Permet de désérialiser l'objet, voir paragraphe suivant
myUser = loadedFileData.user;
myPrefs = loadedFileData.prefs;
}
}
</mx:WindowedApplication>
Ci-dessous la méthode readObjectFromFile qu’on utilise pour dé-sérialiser l’objet sauvegardé. Elle prend comme argument l’objet de type File qu’on a instancié à partir de l’URL du fichier en argument de l’évenement invoke.
public class FileSerializer
{
public static function writeObjectToFile(object:Object, file:File):void
{
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeObject(object);
fileStream.close();
}
public static function readObjectFromFile(file:File):Object
{
if(file)
{
var data:ByteArray = new ByteArray();
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.READ);
fileStream.readBytes(data);
return data.readObject();
}
return null;
}
}